Condition: jumps if ZF = 0 and SF = OF. After CMP a, b the CPU holds a − b. Without overflow, SF gives the sign of the true difference. With overflow (OF = 1) the stored result came out with the wrong sign, so SF is inverted. Either way SF = OF means the true difference is zero or positive, a ≥ b; adding ZF = 0 rules out equality and leaves a > b.

After CMP a, bUnsignedSigned
a = bJE (ZF = 1)JE (ZF = 1)
a ≠ bJNE (ZF = 0)JNE (ZF = 0)
a > bJA (CF = 0 and ZF = 0)JG (ZF = 0 and SF = OF)
a ≥ bJAE (CF = 0)JGE (SF = OF)
a < bJB (CF = 1)JL (SF ≠ OF)
a ≤ bJBE (CF = 1 or ZF = 1)JLE (ZF = 1 or SF ≠ OF)
Prints Y. With JA instead it prints N.
MOV     AL, 5
CMP     AL, -3   ; 5 > -3 signed; unsigned, -3 is 253
MOV     DL, "Y"  ; MOV leaves the flags alone
JG      SHOW1    ; taken: DL stays "Y"
MOV     DL, "N"
SHOW1:
MOV     AH, 02h  ; DOS: print the character in DL
INT     21h

Use the signed family for values that can be negative: temperatures, differences, coordinates, results of IMUL and IDIV. For addresses, sizes and characters use JA.

Range

On the 8086 JG exists only in the SHORT form: two bytes, opcode 7Fh and a signed 8-bit displacement counted from the end of the instruction. The target must lie within −128..+127 bytes of that point. To go farther, invert the test and hop over an unconditional JMP, which can reach the whole segment. MASM 6 makes this rewrite itself when it finds the target out of range (its default OPTION LJMP), so the listing may show two instructions where you wrote one.

JLE     SKIP1    ; the opposite test, a short hop
JMP     FARAWAY  ; any distance in the segment
SKIP1:

Later CPUs

The 80386 added a near form of every conditional jump, 0Fh 8Fh followed by a 16-bit displacement (32-bit in 32-bit code), so from the 386 on JG can reach anywhere in the segment. Code for the 8086 must stay with the short form.